BBC BASIC
« I must be missing something simple .......... »

Welcome Guest. Please Login or Register.
Jan 20th, 2018, 6:07pm


Cross-platform BBC BASIC (Win32, Linux x86, Android, Mac OS-X, Raspberry Pi)

« Previous Topic | Next Topic »
Pages: 1 2 3  Notify Send Topic Print
 locked  Author  Topic: I must be missing something simple ..........  (Read 1487 times)
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #15 on: Aug 9th, 2017, 03:29am »

on Aug 8th, 2017, 11:24pm, hitsware wrote:
Using the below (in BBC) I get "no such System call"

You've omitted the "system" command verb that the original code had, which isn't right. In BBC BASIC you should be using something more like this (untried):

Code:
      SYS "system", "sudo modprobe snd-virmidi snd_index=0"
      SYS "system", "aconnect 20:0 128:0"
      REPEAT
        SYS "system", "amidi -p hw:1,0 -S'90 3C 7F' "
        SYS "system", "amidi -p hw:1,0 -S'90 3C 0' "
        WAIT 22
      UNTIL FALSE
      END 

Of course even if this code works on the Raspberry Pi it isn't 'cross-platform' so runs somewhat contrary to the spirit of BBCSDL.

Richard.
« Last Edit: Aug 9th, 2017, 03:37am by Richard Russell » User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #16 on: Aug 9th, 2017, 05:54am »

Code:
SYS "system", "amidi -p hw:1,0 -S'90 3C 7F' "
SYS "system", "amidi -p hw:1,0 -S'90 3C 0' "
 

It works !!!!!!!!!!!!
How can I put decimal variables into the hex numbers
at the end of the amidi statements ?
FWIW Here's the Ruby way ::::::::::;
Code:
### MIDIPI #######################

# Assumes Timidity installed
# Works on RPi .... Maybe other LinuxMachines ?
# In terminal type 'timidity -iA'
# Leave terminal open

system"sudo modprobe snd-virmidi snd_index=0"#Alsa
system"aconnect 20:0 128:0"                  #Connect

scale=[48,50,52,53,55,57,59,60]              #MidiScale

a=144.to_s(16)                               #Convert
c=127.to_s(16)                               #MidiData
d=0.to_s(16)                                 #to hex

for i in 0..7                                #PlayScale
  b=scale[i].to_s(16)
  system"amidi -p hw:1,0 -S'#{a}#{b}#{c}'"
  system"amidi -p hw:1,0 -S'#{a}#{b}#{d}'"
  sleep 1
end
 
User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #17 on: Aug 9th, 2017, 08:48am »

on Aug 9th, 2017, 05:54am, hitsware wrote:
How can I put decimal variables into the hex numbers

In BBC BASIC the function for converting to a hexadecimal string is STR$~(), note the tilde after the STR$.

Incidentally I didn't address your previous question:

Quote:
Does "SYS" in SDL act as if writing in the terminal?

SYS calls an API function. In BBC BASIC the way to run a 'shell' command is *RUN (conventionally pronounced 'star run') or in most cases just precede the command with an asterisk. So it may well be that this would have worked as well:

Code:
      *amidi -p hw:1,0 -S'90 3C 7F'
      *amidi -p hw:1,0 -S'90 3C 0' 

However you cannot directly incorporate variables in 'star' commands and must use the OSCLI statement in that case. This is all documented in the help file.

Richard.
User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #18 on: Aug 10th, 2017, 3:53pm »

Even though the 2 PRINT's read the same,
only the one without the STR's works in the SYS commands...
I can't figure out how to use the OSCLI ???
Code:
  b0=144: b1=60: b2=127

  SYS "system", " sudo modprobe snd-virmidi snd_index=0 "
  SYS "system", " aconnect 20:0 128:0 "
  PRINT" amidi -p hw:1,0 -S'90 3C 7F'"
  PRINT" amidi -p hw:1,0 -S'"STR$~(b0)" "STR$~(b1)" "STR$~(b2)"'"

  REPEAT
  REM: SYS "system", " amidi -p hw:1,0 -S'90 3C 7F'"
  SYS "system", " amidi -p hw:1,0 -S'"STR$~(b0)" "STR$~(b1)" "STR$~(b2)"'"
  SYS "system", " amidi -p hw:1,0 -S'90 3C 0' "
  WAIT 22
  UNTIL FALSE
  END
 
« Last Edit: Aug 10th, 2017, 3:55pm by hitsware » User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #19 on: Aug 10th, 2017, 8:17pm »

on Aug 10th, 2017, 3:53pm, hitsware wrote:
Even though the 2 PRINT's read the same, only the one without the STR's works in the SYS commands...

PRINT is an unusual statement, for example it can take a list of arguments that are printed one after the other. No other statement in BASIC works like that. Compare these two examples:

Code:
      PRINT "The " "quick " "brown " "fox"
      PRINT "The "+"quick "+"brown "+"fox" 

They appear to do exactly the same thing, but they work completely differently under the hood. Again, compare these two:

Code:
      SYS "system", " amidi -p hw:1,0 -S'" STR$~(b0) " " STR$~(b1) " " STR$~(b2) "'"
      SYS "system", " amidi -p hw:1,0 -S'"+STR$~(b0)+" "+STR$~(b1)+" "+STR$~(b2)+"'" 

The first is your code, but it can't work because SYS isn't like PRINT. The second correctly concatenates the strings using the + operator.

This is very 'basic' stuff!

Richard.
« Last Edit: Aug 10th, 2017, 10:02pm by Richard Russell » User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #20 on: Aug 11th, 2017, 12:02am »

The ide is sure clunky, but it works ;D ..... Thank You once again !!!!
Code:
 REM: ######## RPi Midi Explorer ################

 REM: Assumes Timidity installed
 REM: In terminal enter ' timidity -iA ' ( leave terminal open )

 REM: midi setup
 SYS "system", " sudo modprobe snd-virmidi snd_index=0 "
 SYS "system", " aconnect 20:0 128:0 "

 REM: firstnote
 midipatch = 0: midinote = 55

 REM: start
 PROC_playnote(midipatch, midinote)

 REM: set patches and notes
 REPEAT: REPEAT: x=INKEY(2): UNTIL x <> -1
 IF x = 139 THEN midipatch = midipatch + 1
 IF x = 138 THEN midipatch = midipatch - 1
 IF x = 137 THEN midinote = midinote + 1
 IF x = 136 THEN midinote = midinote - 1
 IF midipatch < 0 THEN midipatch = 0
 IF midipatch >127 THEN midipatch = 127
 IF midinote < 0 THEN midinote = 0
 IF midinote > 127 THEN midinote = 127
 PROC_playnote(midipatch, midinote)
 UNTIL FALSE: END

 REM: play and display
 DEF PROC_playnote(midipatch,midinote)
 SYS "system", " amidi -p hw:1,0 -S'C0 "+STR$~(midipatch)+"'"
 SYS "system", " amidi -p hw:1,0 -S'90 "+STR$~(midinote)+" 7F'"
 WAIT 5   REM: adjust waitime for sustain     
 SYS "system", " amidi -p hw:1,0 -S'B0 7B 0'"
 CLS
 PRINT "midipatch = "; midipatch ;"        midinote = "; midinote
 PRINT " up / down arrows for patch change"
 PRINT "left / right arrows for note change"
 ENDPROC
 





« Last Edit: Aug 11th, 2017, 12:09am by hitsware » User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #21 on: Aug 11th, 2017, 06:47am »

on Aug 11th, 2017, 12:02am, hitsware wrote:
The ide is sure clunky

If by "clunky" you mean slow, the reason is almost certainly that you haven't enabled the GL Driver. As it explains in the installation instructions, BBC BASIC will run very slowly without that driver (and use excessive amounts of CPU time), because the graphics aren't accelerated. You will also find that none of the 3D programs run*.

On the other hand if by "clunky" you mean something else, please give details. The IDE works beautifully on the Raspberry Pi here, almost as well as it works on Linux (86) or Mac OS, which is remarkable given the relatively slow ARM CPU in the RPi.

Richard.

* Actually they do run, but slowly, because SDL falls back to a software driver.
« Last Edit: Aug 11th, 2017, 5:13pm by Richard Russell » User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #22 on: Aug 11th, 2017, 2:59pm »

> If by "clunky" you mean slow,
> the reason is almost certainly that
> you haven't enabled the GL Driver.

Slow is an understatement.
Which model RPi do you have ?
I tried the GL Driver.
It definitely speeds up your visual examples.
Also somewhat speeds up the IDE but not enough.
For some reason it makes my midi not connect.
(maybe needs some pauses to allow execution)
Also seems to cause some irregular blips in the display ?
Anyways ...... SLOW and UNRESPONSIVE undecided
( Compare it to ( say ) LeafPad )
It acts like (perhaps) it is last in the priority list.
I think this is adjustable, but beyond my paygrade grin
I may have messed up the installation ?
First time I installed beyond ' apt-get '
Also I'm an obsessive tinkerer, and may have huh??
The proof in the pudding will be when I do a ditty
and see if it keeps a beat. I can always edit in LeafPad
then copy/paste, but shouldn't have to.
HyperRegards .......... Mike Miller
User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #23 on: Aug 11th, 2017, 4:00pm »

on Aug 11th, 2017, 2:59pm, hitsware wrote:
Slow is an understatement. Which model RPi do you have ?

It's an RPi 3 (the current model). Anything earlier would of course be slow, but then I don't claim BBC BASIC will work on earlier models anyway. wink

Quote:
I tried the GL Driver. It definitely speeds up your visual examples. Also somewhat speeds up the IDE but not enough.

It speeds up all aspects of screen output (graphics and text) and the IDE particularly benefits. On the RPi 3 with GL Driver enabled the IDE is plenty fast enough.

Quote:
For some reason it makes my midi not connect.

As you know, the GL Driver is described as 'experimental' and with good reason. Interference with HDMI sound output is a known bug (it used to be OK, but they seem to have introduced the problem in a recent update). I queried this at the Raspberry Pi forum and apparently there are no plans to fix it in Raspbian Jessie, we will have to wait for Raspbian Stretch for a 'stable' GL Driver.

If the sound problems force you to leave the GL Driver disabled, BBC BASIC will unavoidably be very slow, sorry.

I am absolutely delighted with the Raspberry Pi edition of BBC BASIC: it exceeds my expectations by a large margin (remember, the RPi costs only about 30 so you shouldn't make comparisons with a desktop PC or Android device costing hundreds of pounds). grin

Richard.
User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #24 on: Aug 11th, 2017, 4:44pm »

Quote:
I am absolutely delighted with the Raspberry Pi edition of BBC BASIC:

Me too overall.
I'm delighted by the whole RPi scene.
Jolly Old England has done the world proud !
« Last Edit: Aug 11th, 2017, 4:45pm by hitsware » User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #25 on: Aug 12th, 2017, 1:55pm »

Richard, (or anyone interested)
Would you please try this:
Run the below (slightly modified) routine
Hold down the right arrow key a short time
How fast do the notes change ?

Code:
      REM:#### RPi Midi Explorer #################

      REM: Assumes Timidity installed
      REM: In terminal enter ' timidity -iA ' ( leave terminal open )

      REM: midi setup
      SYS "system", " sudo modprobe snd-virmidi snd_index=0 "
      SYS "system", " aconnect 20:0 128:0 "

      REM: firstnote
      midipatch = 0: midinote = 55

      REM: start
      PROC_playnote(midipatch, midinote)

      REM: set patches and notes
      REPEAT: REPEAT: x=INKEY(0): UNTIL x <> -1
        IF x = 139 THEN midipatch = midipatch + 1
        IF x = 138 THEN midipatch = midipatch - 1
        IF x = 137 THEN midinote = midinote + 1
        IF x = 136 THEN midinote = midinote - 1
        IF midipatch < 0 THEN midipatch = 0
        IF midipatch >127 THEN midipatch = 127
        IF midinote < 0 THEN midinote = 0
        IF midinote > 127 THEN midinote = 127
        PROC_playnote(midipatch, midinote)
      UNTIL FALSE: END

      REM: play and display
      DEF PROC_playnote(midipatch,midinote)
      SYS "system", " amidi -p hw:1,0 -S'C0 "+STR$~(midipatch)+"'"
      SYS "system", " amidi -p hw:1,0 -S'90 "+STR$~(midinote)+" 7F'"
      SYS "system", " amidi -p hw:1,0 -S'B0 7B 0'"
      CLS
      PRINT "midipatch = "; midipatch ;"        midinote = "; midinote
      PRINT " up / down arrows for patch change"
      PRINT "left / right arrows for note change"
      ENDPROC
 



User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #26 on: Aug 12th, 2017, 5:54pm »

on Aug 12th, 2017, 1:55pm, hitsware wrote:
How fast do the notes change ?

I don't get any sound from your program on my RPi 3. sad

The rate at which the notes are produced will in any case depend on the keyboard repeat speed, and since that won't necessarily be consistent between systems I'm not sure what your test is trying to determine.

Also, there's a CLS in your playnote routine and that will slow things down quite a bit.

Richard.
User IP Logged

hitsware
New Member
Image


member is offline

Avatar




PM

Gender: Male
Posts: 49
xx Re: I must be missing something simple ..........
« Reply #27 on: Aug 12th, 2017, 6:21pm »

If you've done the below then it may be the GL driver.........
Anyways it should (has on any other platform) sweep like
running your hand accross a (piano)keyboard .....
~ 20 notes/sec.
This runs more like at least 1/2 second for each note

REM: Assumes Timidity installed
REM: In terminal enter ' timidity -iA ' ( leave terminal open )
User IP Logged

https://www.youtube.com/watch?v=ePhUBBGyVmI
Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #28 on: Aug 12th, 2017, 7:03pm »

on Aug 12th, 2017, 6:21pm, hitsware wrote:
This runs more like at least 1/2 second for each note

Well, the slowness has nothing to do with BBC BASIC, it's just how long those SYS statements happen to take (delete the CLS and PRINT to make sure they are not contributing). I'm sure you didn't seriously think that BBC BASIC would take 0.5 seconds to execute half a dozen statements! A few microseconds more like. smiley

Perhaps you should be running the commands in the background, rather than waiting for them to complete?

Edit: Why are you splitting the MIDI commands into three 'amidi' statements rather than using just one? Surely that just adds unnecessary overhead?

Richard.
« Last Edit: Aug 12th, 2017, 7:09pm by Richard Russell » User IP Logged

Richard Russell
Administrator
ImageImageImageImageImage


member is offline

Avatar




Homepage PM


Posts: 689
xx Re: I must be missing something simple ..........
« Reply #29 on: Aug 12th, 2017, 8:29pm »

on Aug 12th, 2017, 7:03pm, Richard Russell wrote:
Perhaps you should be running the commands in the background, rather than waiting for them to complete?

That makes a big difference (try the code below).

Richard.

Code:
      SYS "system", "sudo modprobe snd-virmidi snd_index=0"
      SYS "system", "aconnect 20:0 128:0"

      midipatch=0
      midinote=55
      PROCplaynote(midipatch, midinote)
      REPEAT
        CASE GET OF
          WHEN 139: IF midipatch < 127 midipatch += 1
          WHEN 138: IF midipatch > 1   midipatch -= 1
          WHEN 137: IF midinote < 127 midinote += 1
          WHEN 136: IF midinote > 1   midinote -= 1
        ENDCASE
        PROCplaynote(midipatch, midinote)
      UNTIL FALSE
      END

      DEF PROCplaynote(midipatch,midinote)
      OSCLI "amidi -p hw:1,0 -S'C0 "+STR$~(midipatch)+" 90 "+STR$~(midinote)+" 7F' ;"
      OSCLI "amidi -p hw:1,0 -S'B0 7B 0' ;"
      PRINT midipatch, midinote
      ENDPROC 

User IP Logged

Pages: 1 2 3  Notify Send Topic Print
« Previous Topic | Next Topic »

Donate $6.99 for 50,000 Ad-Free Pageviews!


This forum powered for FREE by Conforums ©
Sign up for your own Free Message Board today!
Terms of Service | Privacy Policy | Conforums Support | Parental Controls